# Problem 13 on page 99 of Nagle & Saff asks for a prediction of future
# population using the logistic model given by the differential equation
> diffeq:= diff(P(t),t)=a*P(t)-b*P(t)^2;

                           d                        2
                 diffeq := -- P(t) = a P(t) - b P(t)
                           dt

# with the initial condition
> init:= P(0)=1000;

                         init := P(0) = 1000

# Maple's dsolve command yields the following general solution
# (converted into an arrow-defined function):
> P:=unapply(simplify(rhs(dsolve({diffeq, init}, P(t)))),t);

                                          a
        P := t -> 1000 ---------------------------------------
                       1000 b + exp(-a t) a - 1000 exp(-a t) b

# Notice that this result agrees with formula 15 on page 95 of the
# textbook (derived by separating variables and integrating using
# partial fractions).
# To determine the values of the parameters a and b, use the given
# information that the population at time t=7 is 3000, and the
# population at time t=14 is 5000. This gives two equations for two
# unknowns. Here is what Maple's solve command produces:
> solve({P(7)=3000, P(14)=5000}, {a,b}); assign(");

                  {b = 1/42000 ln(5), a = 1/7 ln(5)}

# Thus, the final solution to the differential equation is the
# following:
> simplify(P(t));

                                 6000
                           ----------------
                                (1 - 1/7 t)
                           1 + 5

# Because of the decaying exponential function in the denominator, it is
# clear that the limiting population as t tends to infinity is 6000.
# Maple confirms this:
> limit(P(t), t=infinity);

                                 6000

# The population at time t=21 is approximately
> round(P(21)); 

                                 5769